开启辅助访问 切换到宽版

精易论坛

 找回密码
 注册

QQ登录

只需一步，快速开始

用微信号发送消息登录论坛

新人指南 邀请好友注册 - 我关注人的新帖 教你赚取精币 - 每日签到


求职/招聘- 论坛接单- 开发者大厅

论坛版规 总版规 - 建议/投诉 - 应聘版主 - 精华帖总集 积分说明 - 禁言标准 - 有奖举报

精易论坛»论坛 › 技术专区 › 源码区 › 【汇编】利用驱动程序读取BIOS
返回列表 发新帖
查看: 4679|回复: 5
收起左侧

[易源码分享] 【汇编】利用驱动程序读取BIOS

[复制链接]
鲁凯啸
结帖率：100% (2/2)
发表于 2010-1-1 21:51:10 | 显示全部楼层 |阅读模式   山西省吕梁市
用BIOS的内容作为硬标记进行加密，应用程序可以通过检测bios的特定内容，如主板日期、厂家信息等。如果符合要求，就让程序正常运行；如不符合要求，就判断为盗版，禁止运行。这样可以

起到一定的加密锁的作用。
     如何得到bios的内容呢？我们已经通过驱动程序进入ring0,在ring0中是无所不能的，有一个简单的函数，可以帮助我们达到目的。它就是MmMapIoSpace函数，在DDK文档中看到该函数的说明如下

:
PVOID MmMapIoSpace(
IN PHYSICAL_ADDRESS PhysicalAddress,
IN ULONG NumberOfBytes,
IN MEMORY_CACHING_TYPE CacheType );
在Masm32v8中声明的有4个形参
MmMapIoSpace    proto stdcall :DWORD, :DWORD, :DWORD, :DWORD
为什么参数个数会有不同呢？
原因是MmMapIoSpace第一个参数传递的是一个结构而非结构的指针，而该结构实际的大小是 2 个双字，结果在masm32中表现为总共4个 dword 参数。
调用非常简单，invoke MmMapIoSpace,物理地址低32位,0,长度,MmNonCached
若成功该函数返回影射后的线性地址，否则返回NULL。这样就可以间接达到读取物理地址中内容的目的。

bios开始地址在实模式下是F000:0，也就是0f0000h，长度是64k,也就是10000h
这样我们就可以用一句 invoke MmMapIoSpace,0f0000h,0,64*1024,MmNonCached ;把BIOS的物理地址映射为线性地址，返回值在eax中。
然后把eax指向的线性地址中的内容复制到系统的缓冲区中，让驱动程序传给ring3下的应用程序。
bios_test.bat是驱动源码。
bios_test.asm是调用驱动的ring3级程序，它把驱动传回的bios内容写入文件bios_tst.bin,是16进制的，可以用16进制编辑器来查看。
实际使用时，可以传递一个随机的密钥给驱动程序，驱动程序负责把bios内容加密后返回，这样可以一定程度上增加解密的难度。程序中已经预留了接口，实现起来很简单，有兴趣者可以自己实现。

以下是程序源代码：已在xp和vista下调试通过。



  2. ;goto make
  3. ;文件名bios_test.bat   2009年10月20日用masm32v8和kmdkit1.8在winxp及vista下调试成功。
  4. .386
  5. .model flat, stdcall
  6. option casemap:none
  7. include \masm32\include\w2k\ntstatus.inc
  8. include \masm32\include\w2k\ntddk.inc
  9. include \masm32\include\w2k\ntoskrnl.inc
  10. includelib \masm32\lib\w2k\ntoskrnl.lib
  11. include \masm32\Macros\Strings.mac

  13. IOCTL_GET_INFO equ CTL_CODE(FILE_DEVICE_UNKNOWN, 800h, METHOD_BUFFERED, FILE_READ_ACCESS + FILE_WRITE_ACCESS)


  16. .const
  17. CCOUNTED_UNICODE_STRING    "\\Device\\bios_test", g_usDeviceName, 4
  18. CCOUNTED_UNICODE_STRING    "\\??\\bios_test", g_usSymbolicLinkName, 4


  21. .data
  22. buff1  db 128*512 dup (0f6h) ;
  23. key_1  db 32 dup (0) ;


  26. .code

  28. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  29. ;                                   DispatchCreateClose                                             
  30. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  32. DispatchCreateClose proc pDeviceObject:PDEVICE_OBJECT, pIrp:PIRP

  34.     ; CreateFile was called, to get driver handle
  35.     ; CloseHandle was called, to close driver handle
  36.     ; In both cases we are in user process context here

  38.     mov eax, pIrp
  39.     assume eax:ptr _IRP
  40.     mov [eax].IoStatus.Status, STATUS_SUCCESS
  41.     and [eax].IoStatus.Information, 0
  42.     assume eax:nothing

  44.     fastcall IofCompleteRequest, pIrp, IO_NO_INCREMENT

  46.     mov eax, STATUS_SUCCESS
  47.     ret

  49. DispatchCreateClose endp

  51. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  52. ;                                     DispatchControl                                               
  53. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  55. DispatchControl proc uses esi edi pDeviceObject:PDEVICE_OBJECT, pIrp:PIRP

  57. local status:NTSTATUS
  58. local dwBytesReturned:DWORD    ;实际返回的字节数

  60.     and dwBytesReturned, 0

  62.     mov esi, pIrp
  63.     assume esi:ptr _IRP

  65.     IoGetCurrentIrpStackLocation esi
  66.     mov edi, eax
  67.     assume edi:ptr IO_STACK_LOCATION

  69.     .if [edi].Parameters.DeviceIoControl.IoControlCode == IOCTL_GET_INFO
  70.         .if [edi].Parameters.DeviceIoControl.OutputBufferLength >= 30

  72.             mov eax, [esi].AssociatedIrp.SystemBuffer
  73.                      
  74.                        pushad
  75.                        push eax
  76.                        mov esi,eax
  77.                        mov ecx,30
  78.                        mov edi,offset key_1
  79.                        cld
  80.                        rep movsb  ;保存传过来的数据到key_1,以备做密钥，加密数据后返回。
  81.                        

  83.                       invoke MmMapIoSpace,0f0000h,0,64*1024,MmNonCached ;物理地址映射为线性地址，返回值在eax
  84.                       cmp eax,0   ;eax==0,失败
  85.                       jnz   next_1
  86.                       jmp next_2
  87.             next_1:     
  88.                         mov esi,eax
  89.                         pop edi
  90.                         mov ecx,10000h
  91.                         rep movsb
  92.                         popad

  94.             mov dwBytesReturned, 128*512
  95.             mov status, STATUS_SUCCESS
  96.             jmp next_3
  97.             next_2:pop eax
  98.                    popad
  99.                    mov status, STATUS_INVALID_DEVICE_REQUEST
  100.             next_3:
  101.         .else
  102.             mov status, STATUS_BUFFER_TOO_SMALL
  103.         .endif
  104.     .else
  105.         mov status, STATUS_INVALID_DEVICE_REQUEST
  106.     .endif

  108.     assume edi:nothing

  110.     push status
  111.     pop [esi].IoStatus.Status

  113.     push dwBytesReturned
  114.     pop [esi].IoStatus.Information

  116.     assume esi:nothing

  118.     fastcall IofCompleteRequest, esi, IO_NO_INCREMENT

  120.     mov eax, status
  121.     ret

  123. DispatchControl endp

  125. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  126. ;                                       DriverUnload                                                
  127. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  129. DriverUnload proc pDriverObject:PDRIVER_OBJECT

  131.     ; ControlService,,SERVICE_CONTROL_STOP was called
  132.     ; We are in System process (pid = 8) context here

  134.     invoke IoDeleteSymbolicLink, addr g_usSymbolicLinkName

  136.     mov eax, pDriverObject
  137.     invoke IoDeleteDevice, (DRIVER_OBJECT PTR [eax]).DeviceObject

  139.     ret

  141. DriverUnload endp

  143. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  144. ;                              D I S C A R D A B L E   C O D E                                      
  145. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  147. .code INIT

  149. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  150. ;                                       DriverEntry                                                
  151. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  153. DriverEntry proc pDriverObject:PDRIVER_OBJECT, pusRegistryPath:PUNICODE_STRING

  155.     ; StartService was called
  156.     ; We are in System process (pid = 8) context here

  158. local status:NTSTATUS
  159. local pDeviceObject:PDEVICE_OBJECT

  161.     mov status, STATUS_DEVICE_CONFIGURATION_ERROR

  163.     invoke IoCreateDevice, pDriverObject, 0, addr g_usDeviceName, FILE_DEVICE_UNKNOWN, 0, FALSE, addr pDeviceObject
  164.     .if eax == STATUS_SUCCESS
  165.         invoke IoCreateSymbolicLink, addr g_usSymbolicLinkName, addr g_usDeviceName
  166.         .if eax == STATUS_SUCCESS
  167.             mov eax, pDriverObject
  168.             assume eax:ptr DRIVER_OBJECT
  169.             mov [eax].MajorFunction[IRP_MJ_CREATE*(sizeof PVOID)],            offset DispatchCreateClose
  170.             mov [eax].MajorFunction[IRP_MJ_CLOSE*(sizeof PVOID)],            offset DispatchCreateClose
  171.             mov [eax].MajorFunction[IRP_MJ_DEVICE_CONTROL*(sizeof PVOID)],    offset DispatchControl
  172.             mov [eax].DriverUnload,offset DriverUnload
  173.             assume eax:nothing
  174.             mov status, STATUS_SUCCESS
  175.         .else
  176.             invoke IoDeleteDevice, pDeviceObject
  177.         .endif
  178.     .endif

  180.     mov eax, status
  181.     ret

  183. DriverEntry endp

  185. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  186. ;                                                                                                   
  187. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  189. end DriverEntry

  191. :make

  193. set drv=bios_test

  195. \masm32\bin\ml /nologo /c /coff %drv%.bat
  196. \masm32\bin\link /nologo /driver /base:0x10000 /align:32 /out:%drv%.sys /subsystem:native /ignore:4078 %drv%.obj

  198. del %drv%.obj

  200. pause

复制代码



  2. ;文件名bios_test.asm   2009年10月20日用masm32v8和kmdkit1.8在WinXP及vista下调试成功

  4. ;在winxp下用驱动程序读取bios
  5. .386
  6. .model flat, stdcall
  7. option casemap:none

  9. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  10. ;                                  I N C L U D E   F I L E S                                       
  11. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  13. include \masm32\include\windows.inc

  15. include \masm32\include\kernel32.inc
  16. include \masm32\include\user32.inc
  17. include \masm32\include\advapi32.inc

  19. includelib \masm32\lib\kernel32.lib
  20. includelib \masm32\lib\user32.lib
  21. includelib \masm32\lib\advapi32.lib

  23. include \masm32\include\winioctl.inc

  25. include \masm32\Macros\Strings.mac

  27. IOCTL_GET_INFO equ CTL_CODE(FILE_DEVICE_UNKNOWN, 800h, METHOD_BUFFERED, FILE_READ_ACCESS + FILE_WRITE_ACCESS)
  28. ; Macro definition for defining IOCTL and FSCTL function control codes.  Note
  29. ; that function codes 0-2047 are reserved for Microsoft Corporation, and
  30. ; 2048-4095 are reserved for customers.
  31. ;CTL_CODE MACRO DeviceType:=<0>, Function:=<0>, Method:=<0>, Access:=<0>
  32. ;    EXITM %(((DeviceType) SHL 16) OR ((Access) SHL 14) OR ((Function) SHL 2) OR (Method))
  33. ;ENDM


  36. .const
  37. .data
  38. sysname db "bios_test.sys",0     ;驱动程序名
  39. device db "bios_test",0
  40. driver db "bios_test Driver",0
  41. abyInBuffer db 1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,111,128,128,180,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16;传输试验数据用
  42. abyOutBuffer db 128*512 dup(0)   ;用于存放驱动传回的64kbios数据
  43. name_buffer db 'bios_tst.bin',0  ;读取的bios数据保存到bios_tst.bin
  44. ok_1 db "读取成功，请查看bios_tst.bin",0
  45. dwBytesReturned dd 0
  46. .data?
  47. hFile HANDLE ?        ;文件句柄
  48. SizeReadWrite DWORD ? ;文件中实际写入的字节数
  49. .code

  51. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  52. ;                                       start                                                      
  53. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  55. start proc uses esi edi

  57. local hSCManager:HANDLE
  58. local hService:HANDLE
  59. local acModulePath[MAX_PATH]:CHAR
  60. local _ss:SERVICE_STATUS
  61. local hDevice:HANDLE

  63. local acVersion[16]:CHAR

  65.     ; Open a handle to the SC Manager database
  66.     invoke OpenSCManager, NULL, NULL, SC_MANAGER_ALL_ACCESS
  67.     .if eax != NULL
  68.         mov hSCManager, eax

  70.         ;invoke GetCurrentDirectory, sizeof g_acBuffer, addr g_acBuffer
  71.         push eax
  72.         invoke GetFullPathName, addr sysname, sizeof acModulePath, addr acModulePath, esp
  73.         pop eax

  75.         ; Install service
  76.         invoke CreateService, hSCManager, addr device, addr driver, \
  77.             SERVICE_START + SERVICE_STOP + DELETE, SERVICE_KERNEL_DRIVER, SERVICE_DEMAND_START, \
  78.             SERVICE_ERROR_IGNORE, addr acModulePath, NULL, NULL, NULL, NULL, NULL

  80.         .if eax != NULL
  81.             mov hService, eax

  83.             ; Driver's DriverEntry procedure will be called
  84.             invoke StartService, hService, 0, NULL
  85.             .if eax != 0

  87.                 ; Driver will receive I/O request packet (IRP) of type IRP_MJ_CREATE
  88.                 invoke CreateFile, $CTA0("\\\\.\\bios_test"), GENERIC_READ + GENERIC_WRITE, \
  89.                                 0, NULL, OPEN_EXISTING, 0, NULL

  91.                 .if eax != INVALID_HANDLE_VALUE
  92.                     mov hDevice, eax

  94. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  96.                     ; Driver will receive IRP of type IRP_MJ_DEVICE_CONTROL
  97.                     invoke DeviceIoControl, hDevice, IOCTL_GET_INFO, addr abyInBuffer, sizeof abyInBuffer, addr abyOutBuffer, sizeof abyOutBuffer, addr dwBytesReturned, NULL

  99.                     .if ( eax != 0 ) && ( dwBytesReturned != 0 )

  101.                      
  102.                         invoke MessageBox, NULL, addr ok_1, $CTA0("bios_test"), MB_OK + MB_ICONINFORMATION

  104.                        invoke CreateFile,ADDR name_buffer,\
  105.              GENERIC_READ or GENERIC_WRITE ,\
  106.              FILE_SHARE_READ or FILE_SHARE_WRITE,\
  107.              NULL,CREATE_ALWAYS,FILE_ATTRIBUTE_ARCHIVE,\
  108.              NULL
  109.     mov hFile,eax
  110.     invoke WriteFile,hFile,ADDR abyOutBuffer,128*512,\
  111.              ADDR SizeReadWrite,NULL
  112.     invoke CloseHandle,hFile

  114.                     tt_3:   
  115.                     .else
  116.                         invoke MessageBox, NULL, $CTA0("发送控制失败."), NULL, MB_OK + MB_ICONSTOP
  117.                     .endif

  119. ;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

  121.                     
  122.                     invoke CloseHandle, hDevice  ; Driver will received IRP of type IRP_MJ_CLOSE
  123.                 .else
  124.                     invoke MessageBox, NULL, $CTA0("Device is not present."), NULL, MB_ICONSTOP
  125.                 .endif
  126.                
  127.                 invoke ControlService, hService, SERVICE_CONTROL_STOP, addr _ss
  128.                                         ; DriverUnload proc in our driver will be called
  129.             .else
  130.                 invoke MessageBox, NULL, $CTA0("Can't start driver."), NULL, MB_OK + MB_ICONSTOP
  131.             .endif

  133.             invoke DeleteService, hService
  134.             invoke CloseServiceHandle, hService
  135.         .else
  136.             invoke MessageBox, NULL, $CTA0("Can't register driver."), NULL, MB_OK + MB_ICONSTOP
  137.         .endif
  138.         invoke CloseServiceHandle, hSCManager
  139.     .else
  140.         invoke MessageBox, NULL, $CTA0("Can't connect to Service Control Manager."), NULL, MB_OK + MB_ICONSTOP
  141.     .endif

  143.     invoke ExitProcess, 0

  145. start endp

  147. end start

复制代码



这里读取的bios是经过启动过程初始化后的内容，并不是主板上的bios闪存芯片内的内容，芯片内一般是压缩的，启动过程中自己解压。

通过查看得到的bios_tst.bin,发现有的机器用本程序读出的bios里面有本机的硬盘和光驱型号，这说明bios在启动的过程中，被写入了当前机器的一些信息。机器配置变了，这部分内容也会相应变化，使用bios加密时尽量不要用可变的部分，防止用户换个光驱后被判为盗版软件。



本文是电子管（qq5611409）专为aogo汇编论坛（网址http://www.aogosoft.com/bbs/）所写，转载请保留作者信息和出处。

评分

参与人数 1精币 +2 收起 理由
【微凉清风】 + 2 感谢您的支持,精易有你更精彩!

查看全部评分


回复

使用道具 举报

鲁凯啸
结帖率：100% (2/2)
 楼主| 发表于 2010-1-1 22:26:34 | 显示全部楼层   山西省吕梁市

例程下载
回复 支持 反对

使用道具 举报

易语言起步
结帖率：67% (20/30)
发表于 2012-3-5 21:36:57 | 显示全部楼层   河南省濮阳市
{:3_236:}什么？
回复 支持 反对

使用道具 举报

聋子像哑巴誓爱
发表于 2013-9-22 23:07:17 | 显示全部楼层   山东省烟台市
65+5+9
回复 支持 反对

使用道具 举报

Corre星空
结帖率：100% (1/1)
发表于 2021-7-18 22:49:35 | 显示全部楼层   山西省长治市
文件没了。。。
回复 支持 反对

使用道具 举报

已注销698150
头像被屏蔽
发表于 2022-7-7 22:12:20 | 显示全部楼层   辽宁省大连市
回复 支持 反对

使用道具 举报

返回列表 发新帖
  高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则 致发广告者

发布主题 收藏帖子 返回列表

sitemap| 易语言源码| 易语言教程| 易语言论坛| 诚聘英才| 易语言模块| 手机版| 广告投放| 精易论坛
拒绝任何人以任何形式在本论坛发表与中华人民共和国法律相抵触的言论，本站内容均为会员发表，并不代表精易立场!
论坛帖子内容仅用于技术交流学习和研究的目的，严禁用于非法目的，否则造成一切后果自负！如帖子内容侵害到你的权益，请联系我们！
防范网络诈骗，远离网络犯罪 违法和不良信息举报电话0663-3422125，QQ： 800073686，邮箱：800073686@b.qq.com
Powered by Discuz! X3.4 揭阳市揭东区精易科技有限公司 ( 粤ICP备12094385号-1) 粤公网安备 44522102000125　增值电信业务经营许可证 粤B2-20192173

快速回复 返回顶部 返回列表